IQuestion
1001 996 1000 1005 2004 998 997 999 1004 1003
   
      0⍕Normalize IQuestion
1 1 1 1 2 1 1 1 1 1  

      Normalize←{(⍵×⍴⍵)÷+/|⍵}

         Sales←(10?100)∘.×(10?100)
         Sales[5;5]×←2
         Sales
    507  364 1196  689  611 1235  78 1001 1014 1079
     78   56  184  106   94  190  12  154  156  166
   2691 1932 6348 3657 3243 6555 414 5313 5382 5727
   3393 2436 8004 4611 4089 8265 522 6699 6786 7221
   2457 1764 5796 3339 5922 5985 378 4851 4914 5229
   2886 2072 6808 3922 3478 7030 444 5698 5772 6142
   2847 2044 6716 3869 3431 6935 438 5621 5694 6059
   3900 2800 9200 5300 4700 9500 600 7700 7800 8300
   3471 2492 8188 4717 4183 8455 534 6853 6942 7387
    936  672 2208 1272 1128 2280 144 1848 1872 1992

         0⍕Normalize Sales
    1 1 1 1 1 1 1 1 1 1
    1 1 1 1 1 1 1 1 1 1
    1 1 1 1 1 1 1 1 1 1
    1 1 1 1 1 1 1 1 1 1
    1 1 1 1 2 1 1 1 1 1
    1 1 1 1 1 1 1 1 1 1
    1 1 1 1 1 1 1 1 1 1
    1 1 1 1 1 1 1 1 1 1 
    1 1 1 1 1 1 1 1 1 1   
    1 1 1 1 1 1 1 1 1 1
	

Normalize←{ ⍝ Normalize an array of arbitrary rank - Dyalog V11 version
    AxialNormalize←{(⍵×⍺⊃⍴⍵)÷[(⍳⍴⍴⍵)~⍺]+/[⍺]|⍵}
    LeftChained←{⊃⍺⍺/(⌽⍺),⊂⍵}
    Preprocess←{⍵+1E¯180×0=⍵}
    Postprocess←{⍵×1E¯160<|⍵}
    Postprocess(⍳⍴⍴⍵)AxialNormalize LeftChained⍣≡Preprocess ⍵
}

Normalize←{ ⍝ Normalize an array of arbitrary rank - Compatible version
    AxialNormalize←{(⍵×⍺⊃⍴⍵)÷[(⍳⍴⍴⍵)~⍺]+/[⍺]|⍵}
    LeftChained←{⊃⍺⍺/(⌽⍺),⊂⍵}
    Until←{⍵ ⍵⍵ x←⍺⍺ ⍵:x ⋄ ∇ x}
    Preprocess←{⍵+1E¯180×0=⍵}
    Postprocess←{⍵×1E¯160<|⍵}
    Postprocess{(⍳⍴⍴⍵)AxialNormalize LeftChained ⍵}Until≡Preprocess ⍵
}

Differences between Products

The second sample will show you how to quantify the reasons for deviations in calculations. Though a standard solution already exists, by doing APL examinations we quickly find out that there is something wrong with it, and we can come to more meaningful and realistic results.

A pre-calculation in its simplest form consists of the addition of item expenses, each being a product of price × quantity. These can then be compared by a post-calculation against the actual prices and quantities.

The differences between pre- and post-calculation should desirably be expressible as components of the costs, as only those can get summarized.

Table 5: Bricklayer’s calculation

To determine the reasons for the differences, we need to do a more detailed analysis on a per item basis.

In the German literature about management-economics I found the chart below to explain the concept. (Sorry about not having found it in my English literature[1].)

The pre-calculated costs of an item are represented by the grey field. The difference to the post-calculated cost consists of three fields: one resulting from the difference in the price; one from the difference in quantity; and a third one is called mixed deviation.

Chart 1: 1^st grade and 2^nd grade deviations
[Ref: Zitzmann, Betriebliches Rechnungswesen, Plankosten (chapter 9, page 31), Berner Fachhochschule]

Differences in the prices are caused by inflation or other changes in the market. For differences in quantities the calculating person is responsible. Fortunately the third component, the mixed deviation, is not very much in this sample, so economists tend to neglect it.

Applied to the bricklayer sample, these differences may be separated into the three different causes:

Table 6: Bricklayer’s calculation with 1^st grade and 2^nd grade deviations

Though the total differences in the first table were as low as 65¢, they now expose as being 9.45€ and 11.60€, and furthermore having a mixed difference of 1.50€.

When exchanging the pre- and post-calculation values, peculiarly not only the deviations’ signs change, but also its values:

Table 7: Same as Table 6 with exchanged values for pre- and post-calculation

At this point, one began to have doubts about having found an appropriate solution for the problem. The situation worsens drastically when item costs are the result of three factors:

Costs = Price × Quantity × Rebate Factor [2]

In such cases you will get:

• One deviation based on price difference,
• One deviation based on quantity difference,
• One deviation based on rebate difference and
• Four mixed deviation components.

As it is not unusual that the sum of these four mixed components will be bigger than any of the three meaningful components, the usability of this method becomes rather questionable. So we must search for a better strategy.

To help you follow the quite terse functions, I will explain the resulting strategy for two factors first.

These are the conditions:

a × b + x + y = d × e

a × b + y = a × e

a × b + x = d × b

What we further need, are these two factors…

p = (b × d) ^E

q = (a × e) ^E

...to offer this solution:

x = (d - a) × (b + (e - b) × p / (p + q))

y = (e - b) × (a + (d - a) × q / (p + q))

With the exponent E=0, the mixed deviation is cut into halves:

x = (d - a) × (b + (e - b)/2)

y = (e - b) × (a + (d - a)/2)

With E=1, the bigger causer gets the bigger part of a deviation:

x = (d - a) × (b + (e - b) × (b × d) / ((b × d) + (a × e)))

y = (e - b) × (a + (d - a) × (a × e) / ((b × d) + (a × e)))

Here is the same as a dynamic function:

ProDiff←{E←1
     b←⌽a←⍺+1E¯100
     d←⍵+1E¯100
     h←⌽g←d-a
     q←⌽p←(d×b)*E
     g×b+(h×p)÷p+q}

The additions in lines 2 and 3 are required to avoid division by zero.

These are the calculation results where the deviations are separated according to their origins.

Table 8: Bricklayer’s calculation of two factors with E=0 (mixed component shared equally)

Table 9: Bricklayer’s calculation of two factors with E=1 (appropriately shared to its causers)

With the exponent set to E=1 we get the best matching results, as it shares the mixed deviation component into parts appropriate to its cause.

As previously mentioned, these are calculation samples consisting of three factors. The four mixed deviations could get removed, and the calculation concept is symmetric. [3]

Table 10: Bricklayer’s calculation of three factors with E=0 (mixed component shared equally)

Table 11: Bricklayer’s calculation of three factors with E=1 (appropriately shared to its causer)

In detail, 8.17€ of the difference are inflation based, -7.72€ are based upon the calculator’s fault, and 7.04€ are the result of a purchase manager who failed to ask for the discounts.

ProDiff←{ ⍝ Distribute differences to their causers
    E←1
    2=⍬⍴⌽⍴⍵:⍺{
      b←⌽a←⍺+1E¯100
        d←⍵+1E¯100
        h←⌽g←d-a
        q←⌽p←(d×b)*E
        g×b+(h×p)÷p+q}⍵
    3=⍬⍴⌽⍴⍵:⍺{
        c←1⌽b←1⌽a←⍺+1E¯100
        d←⍵+1E¯100
        i←1⌽h←1⌽g←d-a
        r←1⌽q←1⌽p←a*E
        s←d*E
        pt←1⌽rs←r×s
        pu←2⌽qs←q×s
        puq←1⌽rtp←1⌽qsr←qs×r
        g×(b×c)+((h×c×qs)÷qs+pt)        ...
               +((i×b×rs)÷rs+pu)        ...
               +(h×i×qsr)÷qsr+rtp+puq}⍵
    ⍵-⍺
}
    
         8 2⍕PreCalc
      0.75  165.00    0.88
      2.50    5.00    0.95
      0.30    2.00    0.80
         8 2⍕PostCalc
      0.80  135.00    0.94
      2.70    6.00    0.94
      0.40   30.00    1.00
         8 2⍕PreCalc ProDiff PostCalc
      6.73  ¯20.98    6.88
      1.03    2.46   ¯0.14
      0.41   10.81    0.31

[1] Some translations: Preis = price; Menge = quantity; Preisänderung = price change; Planmenge = planned quantity; Planpreis = planned price; Plankosten = planned costs; Preisabweichung = deviation by price; Grad = grade; Mengenabweichung = deviation by quantity; Gemischte Abweichung = mixed deviation.